UO Outlands Razor Scripts

Created: 03/16/2023, 06:26:13 AM Updated: 03/16/2023, 06:28:24 AM View Change History

1# Fishing with Captcha Detection (cooldown) by Jaseowns
2# UO Outlands
3# Requirements
4#    Setup a cooldown named "Fish" - it must match that name.
5#    If you run the script without the cooldown, it will show you instructions.
6#    but you want to have 3 entries with 10 seconds on each
7#            sysmsg: fish
8#            sysmsg: You retrieve a
9#            overhead: You catch
10#    The script works by checking the cooldown firing
11
12clearsysmsg 
13
14@setvar! jaseFishingCD 9000
15if not timerexists jaseFishingTimer
16    createtimer jaseFishingTimer
17    settimer jaseFishingTimer jaseFishingCD
18endif
19
20cooldown Fish jaseFishingCD
21
22if not cooldown Fish
23    overhead "Please setup a cooldown named:" 34
24    overhead "Fish" 88
25    sysmsg "Please setup a cooldown named:" 34
26    sysmsg "Fish" 88
27    sysmsg "Add these with 10 second cooldown" 66
28    sysmsg "sysmsg: fish"
29    sysmsg "sysmsg: You retrieve a"
30    sysmsg "overhead: You catch"
31    stop
32endif
33
34while not dead     
35
36    if lhandempty
37        if findtype "fishing pole" backpack as item
38            lift item
39            drop self lefthand
40        else
41            overhead "Out of poles!" 34
42            stop
43        endif
44        wait 650
45    endif
46    
47    if insysmsg "The world will save in 15 seconds"
48        for 30
49            overhead 'Waiting for world save...'
50            wait 1000
51            if insysmsg 'save complete'
52                overhead 'Save complete - continue on!' 88
53                replay
54            endif
55        endfor
56    endif
57    
58    if timer jaseFishingTimer >= jaseFishingCD
59        if cooldown Fish
60           hotkey 'Use item in hand'
61           settimer jaseFishingTimer 0
62           cooldown Fish 0
63        else
64            wait 1000
65            if not cooldown Fish
66                overhead 'Captcha break!' 34
67                for 20
68                    overhead 'Awaiting Captcha...' 34
69                    wait 1000
70                    if insysmsg 'Captcha successful'
71                        overhead 'Success - continue on!' 88
72                        wait 1000
73                        replay
74                    endif
75                endfor
76                overhead 'Stopping script' 34
77                stop
78            endif
79        endif
80    endif
81    
82endwhile