Yottawatts's ULTIMATE 2Hander Healing Script by Yottawatts
Related: Snippet2 hand2handerdresshealhealinghealsmagicmagic resistpotionscriptstrengthswapthief proofundressyottawatts
Description from the author:
#Yottawatts's ULTIMATE 2Hander Healing Script 8/10/22
#NOTE: Create a Dress List for your weapon!
#Note 2!: Set your undress container as a trapped pouch or boom chest!!
#You will undress to a trapped pouch and dress from it, no more stolen weapons!
#Note: You cannot set dress container yet or set item hue, use serial
#Remove Notes as needed!
#Remember to reset Dress Serial and Undress bag if you die!(also exit inn for bag)
#NOTE 3: Change dress ID as needed and findtype at line 46
#Hotkeys for potions seem faster!
#Change Notes: Added Cast Function and Reequip to each potion.
#Casting a spell unequips a weapon and bypasses weight limits if overweight
#(no need for 1 hander) (need a spellbook with the spell for this to work)
#Spell Note: Use create food spell in overworld wilderness, recall locks you.
#11 second timer pot
if not timerexists "healpot"
createtimer "healpot"
settimer "healpot" 11000
endif
#11 second cure pot
if not timerexists "curepot"
createtimer "curepot"
settimer "curepot" 11000
endif
#loops the rest while alive
while not dead
#Pause script while saving
if insysmsg "The world is saving, please wait"
while not insysmsg "World save complete"
overhead "World save. Waiting..." 120
wait 500
clearsysmsg
endwhile
endif
#Remove this if you don't have tracking, or save it
if insysmsg 'Now Tracking'
overhead 'MURDERERS RUN!!' 2916
clearsysmsg
endif
clearsysmsg
#This is the re-equip function for a quarter staff
if not findtype 'quarter staff' lefthand
dress 'Staff'
endif
#Drops empty potion bottles, keep or remove
if findtype 'empty bottle%s%' backpack as found
lift found 999
droprelloc 0 0
endif
#Cure pot function
if poisoned and timer 'curepot' > 11000
if findtype 'Orange Potion' backpack
undress 'Staff'
cast 'recall'
hotkey 'Drink Cure'
dress 'Staff'
settimer 'curepot' 0
endif
endif
#Heal Pot Function
if diffhits > 25
if findtype "Yellow Potion" backpack
if timer "healpot" > 11000
wait 100
undress 'Staff'
cast 'recall'
hotkey 'Drink Heal'
wait 250
dress 'Staff'
settimer "healpot" 0
endif
endif
endif
#PVP pouch pop to run away
if paralyzed
[pouch
endif
#Strength and Magic Resist Function
#Maxweight is used because if not, it will sometimes try while buff is still on cooldown
#Only if war mode is on, so only in dungeons!
if warmode on and maxweight = 390 and not findbuff 'Strength'
if findtype 'White Potion' backpack
undress 'Staff'
cast 'recall'
hotkey 'Drink Strength'
hotkey 'Drink Night Sight'
wait 350
dress 'Staff'
endif
endif
wait 50
#Stamina pot if under 40
if diffstam > 40
if findtype 'Red Potion' backpack
undress 'Staff'
cast 'recall'
potion 'refresh'
dress 'Staff'
endif
endif
endwhileHealing script with added tracking message and instructions to make your potion drinking 2hander thief proof!