Tmap decoder (all map types handled) by Jaseowns

1# All types of map decoder by Jaseowns
2# UO Outlands
3# Requirements: 
4#   have a spyglass (can also put spyglasses in maps to decode bag)
5#   selecting a bag with maps to decode
6#   selecting a bag or tome where maps should go when done
7if not varexist "j_restock_undecoded_maps"
8    overhead "Select a bag with undecoded maps" 88
9    setvar j_restock_undecoded_maps
10endif
11
12if not varexist "j_organize_decoded_maps"
13    overhead "Select a bag where decoded maps go" 88
14    setvar j_organize_decoded_maps
15endif
16
17if not findtype "spyglass" backpack
18    if findtype "spyglass" j_restock_undecoded_maps as item
19        overhead "Grabbing spyglass" 34
20        lift item
21        drop backpack -1 -1 -1
22        wait 650
23    else
24        overhead "Need spyglass" 34
25        wait 5000        
26    endif
27    replay
28endif
29
30
31if not findtype "map" backpack
32    dclick j_restock_undecoded_maps
33    wait 200
34    overhead "Restock Map" 88
35    if findtype "map" j_restock_undecoded_maps as map
36        lift map
37        drop backpack -1 -1 -1
38        wait 650
39    endif
40endif
41
42# Close map gump
43// ore
44gumpclose 3367641484
45// skinning
46gumpclose 3473029237
47// lumber
48gumpclose 1332805401
49// treasure
50gumpclose 1520869851
51// fishing
52gumpclose 2589357942
53
54
55if findtype "map" backpack as my_map
56    getlabel my_map desc
57    overhead desc
58    
59    dclicktype "spyglass" backpack
60    wft 1500
61    target my_map
62    
63    @setvar! gumpIdToCheck 0
64    
65    if "ore" in desc
66        @setvar! gumpIdToCheck 3367641484
67    elseif "skinning" in desc
68        @setvar! gumpIdToCheck 3473029237
69    elseif "lumber" in desc
70        @setvar! gumpIdToCheck 1332805401
71    elseif "treasure" in desc
72        @setvar! gumpIdToCheck 1520869851
73    elseif "fishing" in desc
74        @setvar! gumpIdToCheck 2589357942
75    else
76       overhead "Unknown gump!" 34
77    endif
78    
79    waitforgump gumpIdToCheck 1000
80    
81    if "[100.0%" in desc or "(100.0%" in desc
82        dclick j_organize_decoded_maps
83        wait 200
84        overhead "Moving map..." 88
85        lift my_map
86        drop j_organize_decoded_maps -1 -1 -1
87        wait 650
88    else
89        overhead "Updating..."
90        clearsysmsg 
91        while gumpexists gumpIdToCheck
92            gumpresponse 4 gumpIdToCheck
93            wait 500
94            if insysmsg "maximum accuracy"
95                gumpclose gumpIdToCheck
96                replay
97            endif
98        endwhile
99    endif
100    
101    wait 200
102    replay
103else
104    overhead "Out of maps!" 34
105    wait 5000
106    replay
107endif